chipmunkmod/build.gradle

plugins {
    id 'fabric-loom' version "${loom_version}"
}

base.archivesName = project.archives_base_name
version = project.mod_version
group = project.maven_group

repositories {
    mavenCentral()

    // adventure snapshots
    maven {
        url = "https://s01.oss.sonatype.org/content/repositories/snapshots/"
        mavenContent { snapshotsOnly() }
    }
}

dependencies {
    // To change the versions see the gradle.properties file
    minecraft "com.mojang:minecraft:${project.minecraft_version}"
    mappings loom.officialMojangMappings()
    modImplementation "net.fabricmc:fabric-loader:${project.loader_version}"

    // Fabric API
    modImplementation "net.fabricmc.fabric-api:fabric-api:${project.fabric_version}"

    // LuaJ
    include(implementation("org.luaj:luaj-jse:3.0.1"))

    // Configurate
    include(implementation("org.spongepowered:configurate-core:4.2.0"))
    include(implementation("org.spongepowered:configurate-gson:4.2.0"))
    include(implementation("io.leangen.geantyref:geantyref:2.0.1"))

    // Adventure
    include(modImplementation("net.kyori:adventure-platform-fabric:6.8.0"))
    include(implementation("net.kyori:adventure-text-serializer-gson:4.26.1"))
    include(implementation("net.kyori:adventure-text-serializer-legacy:4.26.1"))
}

processResources {
    inputs.property "version", project.version

    filesMatching("fabric.mod.json") {
        expand "version": project.version
    }
}

tasks.withType(JavaCompile).configureEach {
    // Minecraft 1.18 (1.18-pre2) upwards uses Java 17.
    it.options.release = 21

    sourceCompatibility = JavaVersion.VERSION_21
    targetCompatibility = JavaVersion.VERSION_21
}

jar {
    from("LICENSE") {
        rename { "${it}_${base.archivesName}" }
    }
}